#! /bin/csh -f

set echo
set basedir = /web/jsoc/htdocs/data/aia/images
chdir $basedir
set year = `/bin/ls 20[12][0-9] -dct1 | head -1`
chdir $year
set month = `/bin/ls [0-9][0-9] -dct1 | head -1`
chdir $month
set day = `/bin/ls [0-9][0-9] -dct1 | head -1`
chdir $day
set lastwave = `/bin/ls [1-9]* -dct1 | head -1`
set images
set waves
foreach wave ([1-9]*)
    chdir $wave
    set image = `/bin/ls -ct1 | head -1`
    chdir ..
    if ($wave == $lastwave) then
        set lastimage = $image
    endif
    set waves = ($waves $wave)
    set images = ($images "http://jsoc.stanford.edu/data/aia/images/$year/$month/$day/$wave/$image")
end
chdir $basedir
set lasttime = `echo $lastimage | sed -e 's/_//' -e 's/_//' -e 's/__/QQ/' -e 's/_//' -e 's/_//' -e 's/_.*//' -e 's/QQ/_/'`
echo Time"   "$lasttime >newtimes
set n = $#waves
set i = 1
while ($i <= $n)
  echo $waves[$i] $images[$i] >> newtimes
  @ i = $i + 1
end
mv newtimes image_times

@ now = `date +%s`
@ fnow = `date +%s -r image_times`
@ diff = $now - $fnow
if ( $diff > 650 ) then
  echo "Image times file not being updated." > /tmp/image_times_mail
  echo "See /surge40/jsoc/aia/getJP2image_times.csh" >> /tmp/image_times_mail
  /usr/bin/Mail -s "AIA images times file not being updated" jeneen < /tmp/image_times_mail
  rm /tmp/image_times_mail
endif