#! /bin/csh -f

#set echo
set basedir = /web/jsoc/htdocs/data/aia/images
set year = `date -u +%Y`
set month = `date -u +%m`
#set day = `date -u +%d`
set day = `ls -1t $basedir/$year/$month | head -1 | awk -F\/ '{print $1}'`

cd $basedir/$year/$month/$day

set images
set waves

set lastwave = `/bin/ls [1-9]* -dct1 | head -1`

foreach wave ([1-9]*)
    cd $wave
    set image = `/bin/ls -ct1 | head -1`
    cd ..
    if ($wave == $lastwave) then
        set lastimage = $image
    endif
    set waves = ($waves $wave)
    set images = ($images "http://jsoc.stanford.edu/data/aia/images/$year/$month/$day/$wave/$image")
end

cd $basedir
set lasttime = `echo $lastimage | sed -e 's/_//' -e 's/_//' -e 's/__/QQ/' -e 's/_//' -e 's/_//' -e 's/_.*//' -e 's/QQ/_/'`
echo Time"   "$lasttime >newtimes
set n = $#waves
set i = 1
while ($i <= $n)
  echo $waves[$i] $images[$i] >> newtimes
  @ i = $i + 1
end
mv newtimes image_times
cp image_times /tmp28/jsocprod/aia/images

@ now = `date +%s`
@ fnow = `date +%s -r image_times`
@ diff = $now - $fnow
if ( $diff > 650 ) then
  echo "Image times and/or files not being updated." > /tmp/image_times_mail
  echo "See /tmp28/jsocprod/aia/getJP2image_times.csh" >> /tmp/image_times_mail
  echo "Times are in /tmp28/jsocprod/aia/image_times" >> /tmp/image_times_mail
  echo "File last updated $diff seconds ago" >> /tmp/image_times_mail
  /usr/bin/Mail -s "AIA images times file not being updated" jeneen < /tmp/image_times_mail
  rm /tmp/image_times_mail
endif