#! /bin/csh -f


# call with fits file path as only argument
# e.g.   import_lev0_CIF_from_file.csh /tmp20/production/tape_070102/file58/000037460.fits

# set echo
 
set JSROOT = /home/jsoc/hmi/ground

echo $0 $* >>$JSROOT/logs/log_run_q

# setup for CIF 
set FLAGS = "fsn_key=FSN keymap=/home/jsoc/hmi/ground/jsd/lev0.keymap"

set LEV0_PATH = $1
set FITSNAME = $LEV0_PATH
if (-e $FITSNAME) then
      set FITSNAME = `basename $FITSNAME`
      set FSN = `basename $FITSNAME .fits`
      @ FSN = $FSN
      set DSDSNAME = $LEV0_PATH
# now ready to run command, write to script for qsub
      echo " "
      echo Queue $LEV0_PATH 
      set QCMD = $JSROOT/qscripts/"FSN_"$FSN
      if ( -e $QCMD ) then 
        rm -f $QCMD
      endif
      set QLOG = $JSROOT/logs/log.$FSN
      if ( -e $QLOG ) then 
        rm -f $QLOG
      endif
# make script
      echo "#! /bin/csh -f"					 >$QCMD
      echo "set noglob"						>>$QCMD
      # echo "set IMPORT_LEV0 = /home/phil/jsoc/bin/"\$JSOC_MACHINE"/import_egse_lev0" >>$QCMD
      echo "cd /home/jsoc/hmi/ground/scripts"			>>$QCMD
      echo "echo Do $LEV0_PATH 			  >&$QLOG" 	>>$QCMD
      echo "hostname				 >>&$QLOG"	>>$QCMD
      echo "echo -n 'run at '			 >>&$QLOG" 	>>$QCMD
      echo "date				 >>&$QLOG" 	>>$QCMD
      echo "import_egse_lev0 -V in=$LEV0_PATH out=hmi_ground.lev0 dsds=$DSDSNAME $FLAGS  >>&$QLOG" >>$QCMD
      echo "echo -n import done:		 >>&$QLOG" 	>>$QCMD
      echo "show_keys ds=hmi_ground.lev0[$FSN] key=FSN,T_OBS seg=file -p -q >>&$QLOG" >>$QCMD
# execute script in queue
      # qsub -r y -p -10 -q x.q,o.q -o $QLOG -e $QLOG $QCMD
      qsub -r y -p -10 -q x.q -o $QLOG -e $QLOG $QCMD
else
      echo " "
      echo No file found in $LEV0_PATH
endif